Changeset 18 for trunk/aclocal.m4

Timestamp:

Jan 28, 2006, 9:07:52 PM (19 years ago)

Author:

rainer

Message:

Optimized version of tiger algorithm, and basic ingredients for unit testing (part 2)

File:

• trunk/aclocal.m4 (modified) (1 diff)

trunk/aclocal.m4

@@ -1202 +1202 @@
 ])dnl
 
+dnl checks for a known 64 bit programming environment
+dnl AC_RUN_IFELSE(PROGRAM,
+dnl               [ACTION-IF-TRUE], [ACTION-IF-FALSE],
+dnl               [ACTION-IF-CROSS-COMPILING = RUNTIME-ERROR])
+dnl
+AC_DEFUN([SAMHAIN_PRG_ENV],[
+    AC_MSG_CHECKING([for a known 64 bit programming environment])
+    # Compile and run a program that determines the programming environment
+    AC_RUN_IFELSE([
+      AC_LANG_SOURCE([[
+#include <stdio.h>
+int main(int argc,char **argv)
+{
+  if (argc > 1) {
+#if defined(__arch64__)
+  printf("__arch64__\n");
+#elif defined(__ia64__)
+  printf("__ia64__\n");
+#elif defined(__x86_64__)
+  printf("__x86_64__\n");
+#elif defined(__LP64__)
+  printf("__LP64__\n");
+#elif defined(__64BIT__)
+  printf("__64BIT__\n");
+#elif defined(_LP64)
+  printf("_LP64\n");
+#elif defined(_M_IA64)
+  printf("_M_IA64\n");
+#elif defined(_MIPS_SZLONG) && (_MIPS_SZLONG == 64)
+  printf("_MIPS_64\n");
+#else
+choke me
+#endif
+  }
+  return 0;
+}
+      ]])
+    ],[
+      # Program compiled and ran, so get version by adding argument.
+      samhain_prg_ENV=`./conftest$ac_exeext x`
+      samhain_64=yes
+      AC_MSG_RESULT([$samhain_prg_ENV])
+    ],[
+      AC_MSG_RESULT([none])
+        ],[
+      AC_MSG_RESULT([none])
+        ])
+])dnl
+
+AC_DEFUN([SAMHAIN_X86_64],[
+        AC_MSG_CHECKING([for x86_64])
+        AC_TRY_RUN([
+int main() {
+__asm__ volatile (
+"movq %rax, %rax"
+);
+return 0;
+}
+        ],
+        [
+        AC_MSG_RESULT(yes)
+        samhain_64=yes
+        tiger_src=sh_tiger1_64.c
+        AC_DEFINE([TIGER_OPT_ASM],1,[Define to use tiger x86_64 optimized assembly])
+        ],
+        [
+        AC_MSG_RESULT([no])
+        ],[
+        AC_MSG_RESULT([no])
+        ])
+])dnl
+
+
+AC_DEFUN([SAMHAIN_64],[
+samhain_64=no
+tiger_src=sh_tiger1.c
+#
+# if sizeof(unsigned long) = 4, try compiler macros for 64bit
+#
+if test "x$ac_cv_sizeof_unsigned_long" = x4; then
+  if test "x$ac_cv_sizeof_unsigned_long_long" = x8; then
+        SAMHAIN_PRG_ENV
+        if test "x$samhain_64" = xyes; then
+          tiger_src=sh_tiger1_64.c
+        fi
+        #
+        # if GCC and __i386__, use precompiled assembler
+        #
+        if test "x$GCC" = xyes; then
+          AC_MSG_CHECKING([for i386])
+          samhain_i386=no
+          touch conf_foo.h 
+          $CC -E -dM conf_foo.h | egrep '__i386__' >/dev/null 2>&1 && samhain_i386=yes
+          rm -f conf_foo.h
+          if test "x$samhain_i386" = xyes; then
+            tiger_src=sh_tiger1.s
+            AC_DEFINE([TIGER_32_BIT_S],1,[Define to use tiger 32 bit i386 assembler])
+          fi
+          AC_MSG_RESULT([$samhain_i386])
+        fi
+        #
+        #
+        #
+  else
+        samhain_64=no
+        tiger_src=sh_tiger1.c
+  fi
+else
+  #
+  # sizeof(unsigned long) = 8
+  #
+  tiger_src=sh_tiger1_64.c
+  samhain_64=yes
+  #
+  # check for x86_64 (enables assembly optimizations)
+  #
+  if test "x$GCC" = xyes; then
+    SAMHAIN_X86_64
+  fi
+fi
+if test "x$samhain_64" = xyes; then 
+        AC_DEFINE([TIGER_64_BIT],1,[Define to use tiger 64 bit implementation])
+fi
+AC_MSG_CHECKING([for 64 bit environment])
+AC_MSG_RESULT([$samhain_64])
+AC_MSG_CHECKING([for tiger source to use])
+AC_MSG_RESULT([$tiger_src])
+AC_SUBST(tiger_src)
+])dnl
+
+
 dnl Autoconf macros for libprelude
 dnl $id$